Samba 4.0

Настройка сетевых служб, маршрутизации, фаерволлов. Проблемы с сетевым оборудованием.
Правила форума
Убедительная просьба юзать теги [code] при оформлении листингов.
Сообщения не оформленные должным образом имеют все шансы быть незамеченными.
Аватара пользователя
2Casp
проходил мимо
Сообщения: 5
Зарегистрирован: 2008-06-30 12:56:22
Откуда: Ростов-на-Дону

Samba 4.0

Непрочитанное сообщение 2Casp » 2009-11-16 20:02:21

Всем привет!
Уже давно ведутся работы по созданию новой версии samba. Уже и есть альфа версии samba 4.0. Но есть ли люди, которые ее ставили, смотрели. Как работает, можно мнение?
Заранее благодарен :)
Цена тебе - твое слово.

Хостинговая компания Host-Food.ru
Хостинг HostFood.ru
 

Услуги хостинговой компании Host-Food.ru

Хостинг HostFood.ru

Тарифы на хостинг в России, от 12 рублей: https://www.host-food.ru/tariffs/hosting/
Тарифы на виртуальные сервера (VPS/VDS/KVM) в РФ, от 189 руб.: https://www.host-food.ru/tariffs/virtualny-server-vps/
Выделенные сервера, Россия, Москва, от 2460 рублей (8 CPU, 8Gb RAM, 2x500Gb HDD, RAID 3ware 9750):
https://www.host-food.ru/tariffs/vydelennyi-server-ds/
Недорогие домены в популярных зонах: https://www.host-food.ru/domains/

Аватара пользователя
manefesto
Группенфюррер
Сообщения: 6934
Зарегистрирован: 2007-07-20 8:27:30
Откуда: Пермь
Контактная информация:

Re: Samba 4.0

Непрочитанное сообщение manefesto » 2009-11-17 13:41:31

будь первым.
Смысла не вижу особого.
Разве что из-за фич которые тебе явно не нужны.
я такой яростный шо аж пиздеЦ
Изображение

Аватара пользователя
2Casp
проходил мимо
Сообщения: 5
Зарегистрирован: 2008-06-30 12:56:22
Откуда: Ростов-на-Дону

Re: Samba 4.0

Непрочитанное сообщение 2Casp » 2009-11-17 21:39:00

Меня интересует групповые политики на OU. К сожалению не могу организовать их на samba 3.x, если есть идея, буду рад выслушать.
Цена тебе - твое слово.

opt1k
лейтенант
Сообщения: 966
Зарегистрирован: 2007-12-05 9:45:18
Откуда: Mytischi

Re: Samba 4.0

Непрочитанное сообщение opt1k » 2009-11-18 0:40:06

вкуривай реестр, батники и опенлдап, это и есть групповые политики для OU, только ручками и без возможности установки софта через ГП. А лучше купи винду... либо забудь про ГП на самбе.

Аватара пользователя
2Casp
проходил мимо
Сообщения: 5
Зарегистрирован: 2008-06-30 12:56:22
Откуда: Ростов-на-Дону

Re: Samba 4.0

Непрочитанное сообщение 2Casp » 2009-11-18 20:26:52

opt1k писал(а):вкуривай реестр, батники и опенлдап, это и есть групповые политики для OU, только ручками и без возможности установки софта через ГП. А лучше купи винду... либо забудь про ГП на самбе.
я в курсе что групповые политики это реестр windows. Я не могу понять как можно применить для отдельно созданной OU. Если есть мысль, поделись.
Цена тебе - твое слово.

princeps
майор
Сообщения: 2684
Зарегистрирован: 2007-09-25 10:20:59
Откуда: Сочи, Москва
Контактная информация:

Re: Samba 4.0

Непрочитанное сообщение princeps » 2009-11-20 9:21:50

В самбе разве есть OU? В самбе есть группы. ОУ есть в лдап.
Deus quos vult perdere dementat prius
http://www.itforum-sochi.ru

opt1k
лейтенант
Сообщения: 966
Зарегистрирован: 2007-12-05 9:45:18
Откуда: Mytischi

Re: Samba 4.0

Непрочитанное сообщение opt1k » 2009-11-20 10:11:52

Идея есть, надо написать софтину, которая при запуске винды будет дёргать доменное имя пользователя, после чего делать запрос в опендлап для поиска OU к которому он принадлежит, после чего запускать соответствующий скрипт.

Аватара пользователя
2Casp
проходил мимо
Сообщения: 5
Зарегистрирован: 2008-06-30 12:56:22
Откуда: Ростов-на-Дону

Re: Samba 4.0

Непрочитанное сообщение 2Casp » 2009-11-22 17:57:30

Хмм...тогда нужна не софтинка, а скорее всего logon скриптом, на основании группы вбивать в реестр те или иные значения. Есть скрипт, который определяет группу пользователя на AD. Пробывал его запустить на OpenLDAP+samba, идет с ошибкой:

Код: Выделить всё

'==========================================================================  
'  
' VBScript Source File  
'  
' NAME: MapDrivesInGroup.vbs 
'  
' COMMENT: Подключение сетевых дисков на основе групп с записью ошибок в EventLog  
'  
'==========================================================================  
  
Option Explicit  
'On Error Resume Next  
  
Dim WshShell, WshNetwork  
Dim strUserDN, objSysInfo, GroupObj, UserGroups, UserObj 
 
' Задаем имя файлового сервера, при использовании нескольких серверов  
' создаем несколько констант и используем их при вызове MapDrv 
Const FileSrv1 = "\\SRV1" 
 
UserGroups=""    
  
Set WshShell = WScript.CreateObject("WScript.Shell")  
Set WshNetwork = WScript.CreateObject("WScript.Network")  
Set objSysInfo = CreateObject("ADSystemInfo")   
 
strUserDN = objSysInfo.userName   
 
Set UserObj = GetObject("LDAP://" & strUserDN)   
 
For Each GroupObj In UserObj.Groups    
        UserGroups=UserGroups & "[" & GroupObj.Name & "]"    
Next    

'Выводим сообщение пользователю, при входе (принадлежность к группе) 
'MsgBox "Member of "& UserGroups    
 
if InGroup("PurchaseDeportament") then    
        MapDrv "O:", FileSrv1 & "\Purchase","Отдел закупок"        
end if   

if InGroup("SalesDeportament") then    
        MapDrv "X:", FileSrv1 & "\Public","Общий"
        MapDrv "O:", FileSrv1 & "\Sales","Отдел продаж"        
End If   

if InGroup("PrivateADM") then    
        MapDrv "X:", FileSrv1 & "\Public","Общий"
        MapDrv "O:", FileSrv1 & "\PubAdm","Администрация"
        MapDrv "P:", FileSrv1 & "\Sales","Отдел продаж"
        MapDrv "Z:", FileSrv1 & "\Purchase","Отдел закупок"
End If  

'Подключаем принтеры для всех пользователей
wshNetwork.AddWindowsPrinterConnection "\\comp15\HP_3050"
wshNetwork.AddWindowsPrinterConnection "\\comp8\HP_3055"

'Подключаем личный диск пользователя
MapDrv "L:", FileSrv1 & "\Private\" & WshNetwork.UserName, WshNetwork.UserName & "'s личный диск"
  
'==========================================================================  
'  
' Function MapDrv(DrvLet, UNCPath, DrvName)  
'  
' DrvLet - Буква устройства  
' UNCPath - Сетевой путь 
' DrvName - Название диска отображаемое в проводнике Windows 
'  
' COMMENT: Подключение сетевых дисков с записью ошибок в EventLog  
'  
'==========================================================================  
  
  
Function MapDrv(DrvLet, UNCPath, DrvName)  
  
    Dim objFSO, oShell          ' Object variable  
    Dim Msg  
  
    Set objFSO = CreateObject("Scripting.FileSystemObject") 
    Set oShell = CreateObject("Shell.Application") 
 
    On Error Resume Next  
 
    If objFSO.DriveExists(DrvLet) Then  
        WshNetwork.RemoveNetworkDrive DrvLet, true, true 
    End If 
 
    WshNetwork.MapNetworkDrive DrvLet, UNCPath 
    oShell.NameSpace(DrvLet).Self.Name = DrvName 
      
    Select Case Err.Number  
        Case 0            ' No error  
  
        Case -2147023694   
            WshNetwork.RemoveNetworkDrive DrvLet, true, true 
            WshNetwork.MapNetworkDrive DrvLet, UNCPath  
            oShell.NameSpace(DrvLet).Self.Name = DrvName 
               
        Case -2147024811   
            WshNetwork.RemoveNetworkDrive DrvLet, true, true  
            WshNetwork.MapNetworkDrive DrvLet, UNCPath  
            oShell.NameSpace(DrvLet).Self.Name = DrvName 
 
        Case Else  
  
            Msg = "Mapping network drive error: " & _   
                   CStr(Err.Number) & " 0x" & Hex(Err.Number) & vbCrLf & _  
                  "Error description: " & Err.Description & vbCrLf  
            Msg = Msg & "Domain: " & WshNetwork.UserDomain & vbCrLf  
            Msg = Msg & "Computer Name: " & WshNetwork.ComputerName & vbCrLf  
            Msg = Msg & "User Name: " & WshNetwork.UserName & vbCrLf & vbCrLf  
            Msg = Msg & "Device name: " & DrvLet & vbCrLf  
            Msg = Msg & "Map path: " & UNCPath   
  
            WshShell.LogEvent 1, Msg, FileSrv1 
    End Select  
End Function 
 
 
'==========================================================================  
'  
' Function InGroup(strGroup) 
'  
' strGroup - группа, принадлежность к которой проверяем 
'  
' COMMENT: проверка принадлежности пользователя к группе 
'  
'==========================================================================  
 
Function InGroup(strGroup)    
        InGroup=False    
        If InStr(UserGroups,"[CN=" & strGroup & "]") Then    
                InGroup=True    
        End If    
End Function

Цена тебе - твое слово.

Ap0st0l
проходил мимо

Re: Samba 4.0

Непрочитанное сообщение Ap0st0l » 2009-11-30 12:50:45

Скрипт определения группы пользователя под OpenLDAP смотрел кто-нибудь?